Makrá v OpenOffice.org – Skrývanie a odkrývanie textu

Určite sa už aj vám, podobne ako mne, viackrát stalo, že ste dostali dokument (hlavne v DOC formáte), ktorý mal skrytý text, čo spôsobovalo pri ďalšom spracovávaní problémy – napríklad nefungovalo správne vyhľadávanie a pod. Preto je vhodné, aby ste takýto text dokázali odhaliť a následne, podľa potreby, ponechali, upravili, vymazali...

Na druhej strane niekedy sami chcete či potrebujete do dokumentu vložiť skrytý text, napríklad neviditeľné označenie autora, skryté kódové označenie nejakej časti dokumentu atď.



Na toto všetko si môžete pripraviť makro, ktoré to jednoducho vyrieši za vás tak, aby ste dosiahli uspokojivé výsledky. Pre skrývanie textu stačí jednoduchá možnosť – aby makro skrylo označený text. Pravdaže, pokiaľ chcete skrývať viacero textov, je vhodné, aby príslušná možnosť v dialógovom okne zostala otvorená aj počas ďalšej práce, takže znovu použijeme pre uzavieranie dialógového okna čakaciu slučku.



Pre odkrývanie textu bývajú požiadavky väčšie a zložitejšie. V prvom rade väčšinou neviete (pokiaľ nie ste autori dokumentu), kde sa takýto text ukrýva (môže to byť hoci aj jeden jediný znak uprostred ľubovoľného textu). Preto pri jeho hľadaní musíte prezrieť celý dokument – znak za znakom. Následne, po odkrytí skrytého textu väčšinou potrebujete, aby ste tento text ľahko rozoznali od ostatného textu.

Z uvedených dôvodov v dialógovom okne nastavíme niekoľko možností, ako skrytý text pri odkrývaní označiť – umožníme ho prečiarknuť, podčiarknuť, nastaviť jeho farbu a farbu jeho pozadia. Pravdaže, každú z možností môžeme, ale nemusíme použiť, takže si musíme nastaviť aj zašrtávacie políčka, pomocou ktorých príslušné voľby (nezávisle od seba) vôbec sprístupníme. A aby možnosti boli čo najväčšie, použijeme pre prečiarknutie a podčiarknutie rozbaľovacie pole, v ktorom uvedieme všetky možnosti, ktoré nám v súčasnosti OpenOffice.org v tomto smere ponúka.



Pretože problematike rozbaľovacích polí sme sa venovali už dávno pripomeňme, že jednotlivé záznamy zadávate v jeho vlastnostiach do položky „Zoznam záznamov“ s tým, že ich musíte oddeľovať kombináciou kláves „Shift+Enter“ a vlastné zadávanie sa ukončuje klávesou „Enter“.



Aby sme nemali v programe veľa tlačidiel, všetky možnosti spojíme do jedného dialógového okna, pomocou ktorého môžeme paralelne text ukrývať či odkrývať.

dim dlg as object

REM Makro pre skrytie označeného textu
sub Skry_text_Initiated
 dim oKurzor as object
 okurzor= ThisComponent.currentcontroller.getViewCursor() ' viditeľný kurzor
 okurzor.CharHidden=TRUE ' Skrytie textu
end sub

REM Makro pre odkrytie textu v celom dokumente, pričom sa nastavia parametre podľa dialógu
sub Odkry_text_Initiated
 dim oKurzor as object
 dim este as boolean
 dim pom_text as string
 
 oKurzor=StarDesktop.CurrentComponent.Text.CreateTextCursor() ' Vytvoríme nový textový kurzor, ktorým prejdeme celý dokument
 
 oKurzor.gotoStart(false) ' Skočíme na začiatok dokumentu
 
 do
  este=oKurzor.goRight(1,true)
  if este then ' Ak sme označili znak
   if oKurzor.CharHidden then ' Ak je znak skrytý
    oKurzor.CharHidden=FALSE ' Zviditeľnenie textu
    if dlg.model.Check_Preciarkni.State=1 then ' Chceme predtým neviditeľný text po zviditeľnení prečiarknúť
     pom_text=trim(dlg.getControl("Box_Preciarkni").Text)
     select case pom_text
      case "None"
       oKurzor.CharStrikeout=com.sun.star.awt.FontStrikeout.NONE
      case "Single"
       oKurzor.CharStrikeout=com.sun.star.awt.FontStrikeout.SINGLE
      case "Double"
       oKurzor.CharStrikeout=com.sun.star.awt.FontStrikeout.DOUBLE
      case "Don't Know"
       oKurzor.CharStrikeout=com.sun.star.awt.FontStrikeout.DONTKNOW
      case "Bold"
       oKurzor.CharStrikeout=com.sun.star.awt.FontStrikeout.BOLD
      case "Slash"
       oKurzor.CharStrikeout=com.sun.star.awt.FontStrikeout.SLASH
      case "X"
       oKurzor.CharStrikeout=com.sun.star.awt.FontStrikeout.X
     end select
    endif
    
    if dlg.model.Check_Podciarkni.state=1 then ' Chceme predtým neviditeľný text po zviditeľnení podčiarknúť
     pom_text=trim(dlg.getControl("Box_Podciarkni").Text)
     select case pom_text
      case "None"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.NONE
      case "Single"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.SINGLE
      case "Double"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.DOUBLE
      case "Dotted"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.DOTTED
      case "Don't Know"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.DONTKNOW
      case "Dash"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.DASH
      case "Long Dash"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.LONGDASH
      case "Dash Dot"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.DASHDOT
      case "Dash Dot Dot"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.DASHDOTDOT
      case "Small Wave"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.SMALLWAVE
      case "Wave"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.WAVE
      case "Double Wave"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.DOUBLEWAVE
      case "Bold"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.BOLD
      case "Bold Dotted"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.BOLDDOTTED
      case "Bold Dash"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.BOLDDASH
      case "Bold Long Dash"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.BOLDLONGDASH
      case "Bold Dash Dot"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.BOLDDASHDOT
      case "Bold Dash Dot Dot"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.BOLDDASHDOTDOT
      case "Bold Wave"
       oKurzor.CharUnderline=com.sun.star.awt.FontUnderline.BOLDWAVE
     end select
    endif
    
    if dlg.model.Check_Text.state=1 then ' Chceme predtým neviditeľný text po zviditeľnení zafarbiť
     oKurzor.CharColor=(dlg.model.RT.value*256+dlg.model.GT.value)*256+dlg.model.BT.value ' Prepočet zadanej farby na číslo
    endif
    
    if dlg.model.Check_Pozadie.state=1 then ' Chceme predtým neviditeľný text po zviditeľnení podfarbiť
     oKurzor.CharBackColor=(dlg.model.RP.value*256+dlg.model.GP.value)*256+dlg.model.BP.value ' Prepočet zadanej farby na číslo
    endif
   endif
   
   oKurzor.collapseToEnd() ' Zrušíme označenie znaku a skočíme na jeho koniec
  endif
 loop while este ' cyklus opakujeme, kým nebume za posledným znakom dokumentu
end sub

REM Makro, ktoré zneviditeľní dialóg – t.j. nastaví, že sa má ukončiť čakací cyklus (volané stlačením klávesy "Koniec" v dialógu)
sub Koniec_Skry_Odkry_Initiated
 dlg.setVisible(false )' Zneviditeľnenie dialógu
end sub

Rem Volanie dialógu a makra pre skrytie/odkrytie textu
sub Skry_Odkry_text

 DialogLibraries.LoadLibrary("JP_Skryty_text")
 
 dlg=CreateUnoDialog(DialogLibraries.JP_Skryty_text.Dialog_Skry_Odkry)

 dlg.model.Check_Preciarkni.State=0 ' Štandardne ponecháme odkrývaný text v pôvodnom tvare
 dlg.model.Check_Podciarkni.State=0
 dlg.model.Check_Text.State=0
 dlg.model.Check_Pozadie.State=0
 
 dlg.setVisible(true) ' zviditeľnenie dialógu – namiesto dlg.Execute(), aby sa dalo paralelne pracovať s textom
 while dlg.isVisible() ' Cyklus, ktorý čaká na stlačenie klávesy "Koniec" v dialógu (kým je dialóg viditeľný)
  wait 500 ' Časová medzera 500 milisekúnd (0,5 sec) na to, aby sa dalo paralelne pracovať s dokumentom
 wend
 dlg.dispose() ' Zatvorenie dialógu
end sub

Neprehliadnite:

• Akcie, letáky a zľavy
• Pôžičky a úvery pre všetkých
• Turistický sprievodca Budapešťou
• Turistický sprievodca Košicami
• Turistický sprievodca Londýnom
• Turistický sprievodca Prahou
• Turistický sprievodca Viedňou
• Turistický sprievodca Slovenskom

Pozrite si tiež:

«  V Číne imitujú

Úkony spojené s expiráciou  »