Makrá v OpenOffice.org 13/2008
Július Pastierik / 20. 11. 2008, 00:00
V ďalšom pokračovaní seriálu o makrách v OpenOffice.org budeme nepriamo pokračovať minulým dielom, pretože si ukážeme makrá pre vkladanie slov do používateľských slovníkov z aktuálneho dokumentu.
V minulom dieli sme si ukázali možnosti importu a exportu používateľských slovníkov pomocou textových súborov. Pri bežnej práci sa nám však viac hodí, ak dokážeme do slovníka vložiť práve napísané slovo, pokiaľ sa v slovníku nenachádza.
Toto ocenia najmä tí používatelia, ktorí píšu rozsiahle dokumenty, kde prípadná následná kontrola gramatiky (klávesová skratka F7) trvá príliš dlho. Samozrejme, keď už budeme tvoriť makro pre vloženie slova z aktuálne spracovávaného dokumentu, pripravíme aj funkciu pre vloženie jeho všetkých slov do slovníka, čím vytvoríme alternatívu k importu z obyčajných TXT súborov.
Preto, aby sme mohli tieto funkcie vytvoriť, musíme si podobne, ako minule, najprv pripraviť dialógové okno, kde budeme vyberať slovník, do ktorého budeme slová pridávať. Teraz bude obsahovať iba rozbaľovací zoznam zo slovníkmi a tlačidlo „OK“ a „Cancel“.
Vlastné makrá naprogramujeme tak, aby, pokiaľ slovník ešte nie je vybraný, otvorili tento dialóg, inak sa budú slová už priamo vkladať. V praxi sa vloženie slova do slovníka prejaví tak, že ho OpenOffice.org nebude podčiarkovať ako neznáme. Pokiaľ k makru priradíme vhodnú klávesovú skratku, týmto spôsobom si značne zrýchlime vkladanie nových slov do slovníka, pretože sa nebude (vlastne zbytočne) otvárať dialógové okno „Preklepy“, kde musíme pri pridávaní slova vždy vybrať príslušný slovník.
REM Import slov z aktuálneho dokumentu do vybraného používateľského slovníkova
private dialog_word_import as object
global slovo2slovnik_name as string
Sub Vyber_slovnik
'Makro pre výber slovníka pre import slov z dokumentu
dim pom_zoznam, zoznam, slovniky, dialog_slovo2slovnik as object
DialogLibraries.LoadLibrary("slovo2slovnik") ' Otvorenie knižnice
dialog_slovo2slovnik=CreateUnoDialog (DialogLibraries.slovo2slovnik.Dialog_slovo2slovnik) ' Sprístupnenie dialógu
if slovo2slovnik_name="" then
' Ak nevyberieme iný slovník, použije sa "standard.dic"
slovo2slovnik_name="standard.dic"
endif
' Načítanie zoznamu slovníkov
pom_zoznam=createUnoService("com.sun.star.linguistic2.DictionaryList") ' sprístupnenie zoznamu slovníkov
zoznam=pom_zoznam.GetDictionaries ' zoznam slovníkov
slovniky=dialog_slovo2slovnik.getControl ("zoznam_slovnikov") ' prístup k zoznamu slovníkov v dialógu
' Vloženie názvov slovníkov do zoznamu v dialógu
for i=LBound(zoznam) to UBound(zoznam)
slovniky.AddItem(zoznam(i).Name, slovniky.ItemCount)
next i
slovniky.Text=slovniky.Items(0) ' Zobrazenie prvej položky
' Spustenie dialógu pre výber slovníka pre Import slov
if Dialog_slovo2slovnik.Execute()=1 then
' Ak sme stlačili "OK", tak nastavíme slovník
slovo2slovnik_name=Dialog_slovo2slovnik.getControl("zoznam_slovnikov").Text ' Názov vybraného slovníka
endif
' Vymazanie dialógu
Dialog_slovo2slovnik.dispose()
End Sub
Sub Import_vsetkych_slov_do_slovnika
' Makro pre import všetkých slov z dokumentu do vybraného slovníka
dim pom_zoznam, slovnik as object
dim slovo as string
dim dokument, kurzor as object
dim koniec as boolean
dim pocet as long
if slovo2slovnik_name="" then
' Ak nemáme vybraný slovník, spustíme najprv dialóg pre jeho výber
Vyber_slovnik
endif
pom_zoznam=createUnoService ("com.sun.star.linguistic2.DictionaryList") ' sprístupnenie zoznamu slovníkov
slovnik=pom_zoznam.GetDictionaryByName(slovo2slovnik_name) ' Sprístupnenie zadaného slovníka
dokument=StarDesktop.CurrentComponent
kurzor=dokument.Text.createTextCursor() ' Kurzor pre pohyb po dokumente
pocet=0 ' Počet naimportovaných slov
kurzor.collapseToStart() ' Aby nebolo nič označené
kurzor.gotoStart(false) ' Skočíme na začiatok dokumentu
do
koniec=false ' Ešte musíme spracovať slová
do
' Pokiaľ nie sme na začiatku slova, posunieme sa o jeden znak vpravo
if not kurzor.isStartOfWord then
koniec=not(kurzor.goright(1,false)) ' Posun s indikáciou konca súboru
endif
loop until (koniec or kurzor.isStartOfWord)
if not koniec then
' Ak nie sme na konci súboru, spracujeme slovo
kurzor.gotoEndOfWord(true) ' Skočíme na koniec slova a označíme ho
slovo=trim(kurzor.String) ' Označené slovo bez medzier na začiatku a konci
if slovo<>"" then
' Ak je označené slovo neprázdne, tak ho vložíme do slovníka
slovnik.Add(slovo, False, "") ' Vloženie slova do slovníka
pocet=pocet+1
endif
koniec=not(kurzor.goRight(1,false)) ' a presunieme sa na ďalší znak
endif
loop until Koniec ' Skončíme, ak sme sa nepresunuli na ďalší znak – koniec súboru
'Vypíšeme si počet vložených slov
msgbox "Importovaných "+pocet+" slov do slovníka '"+slovo2slovnik_name+"'."
End Sub
Sub Import_aktualneho_slova_do_slovnika
' Makro pre import aktuálneho slova do vybraného slovníka
' Môžeme sa nachádzať na začiatku, v prostriedku alebo aj na konci slova, ktoré chceme vložiť
dim dokument, vid_kurzor, kurzor as object
dim pom_zoznam, slovnik as object
dim slovo as string
if slovo2slovnik_name="" then
' Ak nemáme vybraný slovník, spustíme najprv dialóg pre jeho výber
Vyber_slovnik
endif
pom_zoznam=createUnoService ("com.sun.star.linguistic2.DictionaryList") ' sprístupnenie zoznamu slovníkov
slovnik=pom_zoznam.GetDictionaryByName(slovo2slovnik_name) ' Sprístupnenie zadaného slovníka
dokument=StarDesktop.getCurrentComponent()
vid_kurzor=dokument.getCurrentController().getViewCursor() ' viditeľný kurzor
kurzor=vid_kurzor.getText().createTextCursorByRange(vid_kurzor) ' vytvoríme pomocný kurzor podľa viditeľného kurzora
kurzor.collapseToStart() ' Aby nebolo nič označené
if not kurzor.isStartOfWord() then
' Ak nie sme na začiatku slova, skočíme tam
kurzor.gotoStartOfWord(false)
endif
kurzor.gotoEndOfWord(true) ' Skočíme na koniec slova a označíme ho
slovo=trim(kurzor.String) ' Označené slovo bez medzier na začiatku a konci
if slovo<>"" then
' Ak je označené slovo neprázdne, tak ho vložíme do slovníka
slovnik.Add(slovo, False, "") ' Vloženie slova do slovníka
endif
end sub