Makrá v OpenOffice.org 5/XIV. – Formátovanie dokumentu 6
Július Pastierik / 04. 04. 2007, 00:00
V ďalšom pokračovaní programovania makier v OpenOffice.org sa budeme venovať spoločným funkciám pre vlastné formátovanie dokumentu, ako je vyhľadávanie, výmena vo vnútri nájdeného reťazca a pod.
V minulom dieli sme si uviedli funkcie pre automatické vkladanie nezalomiteľnej medzery za jednoznakové predložky a spojky priamo počas písania textu. Teraz nám už nezostáva nič iné, ako si uviesť makrá pre ostatné formátovanie dokumentu, ktoré sme si v našom seriáli už viackrát spomínali. Teraz ich upravíme na nastavenia podľa parametrov, ktoré si môžeme definovať v používateľských profiloch a nebudeme sa už venovať iným verziám.
Vlastné formátovacie funkcie si uložíme do modulu „Formatovanie_funkcie“ a ponecháme ich v obecnom tvare, aby sa dali použiť aj bez obmedzení, ktoré sú nastavené v používateľských príznakoch pre formátovanie dokumentu. Tieto príznaky budeme následne akceptovať až vo funkciách celkového formátovania dokumentu (tieto si uložíme do modulu „Formatovanie“), čím dosiahneme obecnejšie možnosti ich použitia.
Hoci sa makrá oproti naposledy uverejneným verziám dosť pomenili, sú dostatočne okomentované na to, aby sme sa im osobitne venovali a preto znovu uvedieme iba ich zdrojové texty. Vzhľadom na veľký rozsah týchto zdrojových textov dnes si znovu uvedieme iba makrá pre vyhľadávanie a nahrádzanie textu.
REM Definície spoločných premenných sú úplne pred definíciou podprogramov
dim Dokument, Vymena, Hladaj as object
dim NM, TAB, WJ as string
REM Inicializácia spoločných premenných
sub Init
Dokument=ThisComponent
Vymena=Dokument.createReplaceDescriptor()
Hladaj=Dokument.createSearchDescriptor()
NM=chr$(&HA0) ' Nezalomiteľná medzera – hexadecimálny kód A0
TAB=chr$(&H09) ' Tabelátor – hexadecimálny kód 09
WJ=chr$(&H2060) ' Word Joiner
end sub
REM Výmena reťazca Co za reťazec Za
function Vymen(Co, Za as string, Regularne, Cele_slova, Velke_pismena as Boolean) as long
Vymena.SearchString=Co
Vymena.ReplaceString=Za
Vymena.SearchRegularExpression=Regularne
Vymena.SearchWords=Cele_slova
Vymena.SearchCaseSensitive=Velke_pismena
Vymen=Dokument.replaceAll(Vymena)
end function
REM Vlastná výmena reťazca Co za reťazec Za vo vnútri reťazca V_Com
function Zamen_Vo_Vnutri (V_Com, Co, Za as string) as string
dim pom as string
dim i, j as long
pom=V_Com
i=instr(V_Com, Co)
j=len(V_Com)-i-len(Co)+1
if i>0 then
pom=left(V_Com, i-1)+Za
if j>0 then
pom=pom+right(V_Com, j)
end if
end if
Zamen_Vo_Vnutri=pom
end function
REM Výmena vnútorného reťazca Co za reťazec Za hľadaním reťazca V_Com
function Vymen_hladanim(V_Com, Co, Za as string, Regularne, Cele_slova, Velke_pismena as Boolean) as long
dim nasiel as object
dim kolko as long
Hladaj.searchString=V_Com
Hladaj.SearchRegularExpression=Regularne
Hladaj.SearchWords=Cele_slova
Hladaj.SearchCaseSensitive=Velke_pismena
kolko=0
nasiel = Dokument.findFirst(Hladaj)
Do While NOT isNull(nasiel)
if len(nasiel.String)>0 then
nasiel.String=Zamen_Vo_Vnutri(nasiel.String, Co, Za)
kolko=kolko+1
end if
nasiel = Dokument.findNext(nasiel.End, Hladaj)
Loop
Vymen_hladanim=kolko
end function
REM Vyhľadanie reťazca V_Com a na pozíciu Kde do neho vloží reťazec Co
function Vloz_hladanim(V_Com, Co as string, Kde as long, Regularne, Cele_slova, Velke_pismena as Boolean) as long
dim nasiel as object
dim kolko, i, j as long
dim pom as string
Hladaj.searchString=V_Com
Hladaj.SearchRegularExpression=Regularne
Hladaj.SearchWords=Cele_slova
Hladaj.SearchCaseSensitive=Velke_pismena
kolko=0
i=kde+1
nasiel = Dokument.findFirst(Hladaj)
Do While NOT isNull(nasiel)
if len(nasiel.String)>0 then
j=len(nasiel.String)-i+1
pom=left(nasiel.String, i-1)+Co
if j>0 then
pom=pom+right(nasiel.String, j)
end if
nasiel.String=pom
kolko=kolko+1
end if
nasiel = Dokument.findNext(nasiel.End, Hladaj)
Loop
Vloz_hladanim=kolko
end function
Na budúce: Makrá pre nahrádzanie vymazávanie viacnásobných medzier a prázdnych odstavcov, alebo tie zdrojové texty sú naozaj veľmi dlhé.