Július Pastierik / 01. 12. 2005, 00:00
V dnešnom dieli nášho seriálu o programovaní makier v OpenOffice.org dokončíme popis základných príkazov jazyka StarOffice Basic – ako inak – znovu na našom príklade o odstraňovaní viacnásobných medzier.
Minule sme si predstavili prvé dve verzie príkazu DO. Zostávajú nám ešte dve, a preto začneme priamo nimi.
Príkaz DO
Variant 3
DO
' … opakované príkazy
LOOP WHILE podmienka
Cyklus sa opakuje dovtedy, kým je splnená zadaná podmienka. Na rozdiel od prvých dvoch variant sa príkazy vo vnútri cyklu vykonajú minimálne jeden krát. Táto vlastnosť sa nám veľmi hodí, pretože aj vymazávanie viacnásobných medzier musíme urobiť aspoň raz.
SUB dvojita_medzera
DIM Dokument, Vymena AS object
DIM kolko, teraz AS Long
Dokument=ThisComponent
Vymena=Dokument.createReplaceDescriptor()
Vymena.SearchString=" "
Vymena.ReplaceString=" "
kolko=0
DO
REM aktuálny počet zámien uložíme do premennej teraz
teraz=Dokument.replaceAll(Vymena)
REM spočítame úplne všetky zámeny
kolko=kolko+teraz
REM opakujeme kým aktuálny počet zámien je nenulový
LOOP WHILE teraz<>0
msgbox("Nahradených "+kolko+" dvojnasobnych medzier.",0,"Viacnasobne medzery")
END SUB
Variant 4
DO
'… opakované príkazy
LOOP UNTIL podmienka
Posledná verzia cyklusu DO sa ukončí vtedy, keď bude splnená zadaná podmienka. Tak isto ako v predchádzajúcej variante, aj teraz sa príkazy vo vnútri cyklu vykonajú minimálne jeden krát. Naše makro pre výmeny viacnásobných medzier môžeme teraz naprogramovať takto:
SUB dvojita_medzera
DIM Dokument, Vymena AS object
DIM kolko, teraz AS Long
Dokument=ThisComponent
Vymena=Dokument.createReplaceDescriptor()
Vymena.SearchString=" "
Vymena.ReplaceString=" "
kolko=0
DO
REM počet zámien uložíme do premennej teraz
teraz=Dokument.replaceAll(Vymena)
REM spočítame všetky zámeny
kolko=kolko+teraz
REM opakujeme kým aktuálny počet zámien je nenulový
LOOP UNTIL teraz=0
msgbox("Nahradených "+kolko+" dvojnasobnych medzier.",0,"Viacnasobne medzery")
END SUB
Na príklade jedného a toho istého algoritmu pre odstraňovanie viacnásobných medzier sme si ukázali štyri varianty príkazu DO. Pokiaľ si dobre všimnete drobné rozdiely v jednotlivých verziách týchto makier, ľahko pochopíte ich rozdielne správanie.
Príkaz FOR
Niekedy potrebujeme urobiť cyklus pre určitý rad hodnôt, ktoré sa pravidelne menia o určitý krok, pričom dopredu poznáme ich počiatočnú a koncovú hodnotu. Vtedy úspešne využijeme cyklus FOR:
FOR premenna=pociatocna_hodnota TO koncova_hodnota STEP krok
' … opakované príkazy
NEXT premenna
Cyklus FOR je vlastne iba špeciálnym zjednodušeným zápisom cyklu DO, ktorý sa v krajnom prípade nevykoná ani raz:
premenna=pociatocna_hodnota
DO WHILE premenna<= koncova_hodnota
' … opakované príkazy
premenna=premenna+krok
LOOP
Tento cyklus môžeme napríklad použiť na výpočet n-faktoriálu a potom môžeme funkciu pre jeho výpočet naprogramovať napríklad takto:
function faktorial(n as long) as long
dim pom_faktorial as long
pom_faktorial=1
FOR i = 2 TO n STEP 1
pom_faktorial=pom_faktorial*i
NEXT i
faktorial=pom_faktorial
end function
V uvedenom príklade sa premenná i zväčšovala o 1. V takýchto prípadoch nemusí krok vôbec zadávať a celý príkaz môže vyzerať takto:
pom_faktorial=1
FOR i = 2 TO n
pom_faktorial=pom_faktorial*i
NEXT i
Samozrejme, krok nemusí byť len kladný, ale aj záporný:
pom_faktorial=1
FOR i = n TO 2 STEP -1
pom_faktorial=pom_faktorial*i
NEXT i
Ako premenné tohto cyklu však nemusia byť iba čísla, ale aj písmená. Napríklad cyklus pre všetky malé písmená abecedy by mohol vyzerať takto:
FOR znak = "a" TO "z"
' … opakované príkazy
NEXT znak
Možnosti cyklu FOR však nekončia ani písmenami, pretože môžeme ako premennú použiť dokonca poradové indexy zo zoznamu hodnôt. Je to vlastne špeciálny prípad cyklusu číselného, kde počiatočná a koncová hodnota odkazuje na prvý a posledný prvok zo zoznamu. Napríklad cyklus pre všetky jednoznakové predložky a spojky by mohol aj z definíciou príslušného zoznamu vyzerať takto:
DIM predlozky() AS STRING
DIM i AS LONG
predlozky() = ARRAY("a", "i", "k", "o", "s", "u", "v", "z")
FOR i = LBOUND(predlozky()) TO UBOUND(predlozky())
' … opakované príkazy
NEXT i
Príkaz EXIT
Niekedy sa môže stať, že potrebujeme cyklus DO alebo FOR ukončiť predčasne – niekde uprostred jeho vykonávania. Presne na tento účel slúži príkaz EXIT, ktorý okamžite ukončí príslušný cyklus.
FOR premenná = od TO po STEP krok
'… príkazy
EXIT FOR
'… príkazy
NEXT premenná
DO
'… príkazy
EXIT DO
'… príkazy
LOOP
Príkaz EXIT využijeme napríklad vtedy, ak chceme zistiť, ktorý akademický titul sa vyskytuje ako prvý v aktuálnom dokumente. Takéto hľadanie môžeme naprogramovať napríklad takto:
SUB hladaj_titul
DIM tituly() AS STRING
DIM i AS INTEGER
DIM ktory AS string
DIM dokument, hladaj AS OBJECT
tituly() = ARRAY("akad.", "Bc.", "Csc.", "doc.", "Dr.", "DrSc.", "h.c.", "Ing.", "arch.", "JUDr.", "Mgr.", "MUDr.", "MVDr.", "PaedDr.", "PharmDr.", "PhDr.", "PhMr.", "prof.", "RNDR", "ThDr.")
dokument=ThisComponent
hladaj=Dokument.createReplaceDescriptor()
ktory=""
FOR i = LBOUND(tituly()) TO UBOUND(tituly())
REM Na zistenie či sa hľadaný reťazec v dokumente nachádza alebo nie použijeme „fintu“
REM jeho zámeny za ten istý reťazec s tým, že zistíme počet týchto „zámen“.
hladaj.SearchString=tituly(i)
hladaj.ReplaceString=tituly(i)
if Dokument.replaceAll(Vymena)<>0 then
ktory=tituly(i)
EXIT FOR
END IF
NEXT i
msgbox("Prvy titul je: "+ktory,0,"Hladanie akademickych titulov")
END SUB
Na budúce: premenné jazyka StarOffice Basic, alebo čo všetko píšeme za príkaz DIM.
Copyright © 2002 - 2013 inet.sk, s. r. o. | Všetky práva vyhradené | Neprešlo jazykovou úpravou | ISSN 1336-1899
Využívame kvalitný webhosting za rozumnú cenu od Inet.sk