Makrá v OpenOffice.org: Oddeľovanie rádov v číslach

Július Pastierik  /  27. 04. 2011, 00:00

Píšete v textových dokumentoch číslice a potrebujete, aby ste mali medzi tisíckami vložené nezalomiteľné medzery? V dnešnom dieli seriálu o programovaní makier si ukážeme funkciu, pomocou ktorej dokážete na jedno kliknutie upraviť všetky číslice v dokumente.

Pre používateľov, ktorí často píšu číslice v textových dokumentoch, nie je práve príjemná tá skutočnosť, že v prípade potreby optického oddelenia tisícov medzerou túto musia vkladať ručne (čo napríklad v module Calc dokáže OpenOffice.org urobiť sám). Preto je vhodné, aby sme si na takéto účely naprogramovali funkciu, ktorá to urobí za nás.

V makre musíme vyhľadať všetky čísla – samozrejme, jedno či celé alebo reálne, pričom je vhodné, aby sme umožnili zadávať ako desatinný oddeľovač ako čiarku, tak aj bodku (pre prípad, že píšeme cudzojazyčné dokumenty, kde sa používa desatinná bodka). Následne musíme z čísiel (ak tomu vôbec zodpovedá počet ich cifier) extrahovať celú časť, túto naformátovať (v tomto smere môžeme použiť podobné formátovanie, ako ho umožňuje modul Calc), číslo musíme znovu spojiť s oddelenou desatinnou časťou (ak bola zadaná) a v poslednom kroku ho musíme vložiť namiesto predtým nájdeného čísla.



Aby sme vedeli, že náhrady boli vykonané, v závere vypíšeme ich počet. Pri výpise budeme uvažovať s prípadnou jazykovou lokalizáciou tejto funkcie.



Toľko k uvedeniu problematiky, to, ako makro funguje je vidieť na zosnímaných obrazovkách.

REM Funkcia pre zistenie jazyka OO.o
function Jazyk_OOo as string
 dim ConfigProvider, MasterKey as object
 dim NodePath(0) as new com.sun.star.beans.PropertyValue
  
 NodePath(0).Name = "nodepath"
 NodePath(0).Value = "org.openoffice.Setup/L10N/"
 
 ConfigProvider = createUnoService("com.sun.star.configuration.ConfigurationProvider")
 MasterKey = ConfigProvider.createInstanceWithArguments("com.sun.star.configuration.ConfigurationAccess", NodePath())
 Jazyk_OOo = left(trim(MasterKey.getByName("ooLocale")),2) '"sk", "cs", …
end function

REM Procedúra pre formátovanie všetkých čísiel (oddelenie rádov znakom NBSP)
sub Cislo_s_medzerami
 REM Pre hľadanie čísiel a ich formátovanie
 dim oDokument : oDokument=ThisComponent
 dim oHladaj : oHladaj=oDokument.createSearchDescriptor()
 dim oNasiel
 dim sPom$, sCela$
 dim kolko as long
 REM Pre načítanie jazykovej lokalizácie
 dim riadok, premenna, definicia as string
 dim rovna as integer
 dim sf, inStream, inFile ' Pre čítanie z lokalizačného súboru
 dim sText1$ : sText1="Naformátovaných "
 dim sText2$ : sText2=" čísiel."
 
 kde=basiclibraries.getLibraryLinkURL("JP_cislo_rady") ' Adresár, kde je rozšírenie nainštalované
 sNazov=left(kde,len(kde)-10)+"JP_cislo_rady_"+Jazyk_OOo+".txt" ' Súbor s jazykovou lokalizáciou
 on error resume next
 
 if fileexists(sNazov) then ' Ak lokalizačný súbor existuje, tak načítame definície do premenných
  sf = createUnoService("com.sun.star.ucb.SimpleFileAccess")
  inStream = sf.openFileRead(sNazov)
  inFile = createUnoService("com.sun.star.io.TextInputStream")
  inFile.InputStream = inStream
  inFile.Encoding = "UTF-8" ' lokalizačný súbor musí byť v UTF-8, inak nebude dobrá diakritika
  
  Do While not inFile.IsEOF
   riadok = inFile.readLine ' namiesto Line Input #subor, riadok
   rovna=instr(riadok,"=")
   if rovna<>0 then
    premenna=trim(left(riadok,rovna-1)) ' Budeme ignorovať medzery
    definicia=trim(right(riadok,len(riadok)-rovna))
    select case premenna
     case "Text1"
      sText1=definicia+" "
     case "Text2"
      sText2=" "+definicia
    end select
   end if
  loop
  ' Zatvorenie definičného súboru – namiesto close #subor
  inStream.closeInput
  inFile.closeInput
 end if
 
 REM Vlastné hľadanie
 oHladaj.searchString="[:digit:]*(,|.|[:digit:])[:digit:]*" ' Hľadanie čísiel s desatinnou bodkou alebo čiarkou v tvaroch "1" "1,1" "1.1" "1," "1." ",1" ".1"
 oHladaj.SearchRegularExpression=True
 kolko=0 ' Počet nájdených výskytov
 oNasiel = oDokument.findFirst(oHladaj) ' Hľadanie prvého výskytu v dokumente
 Do While NOT isNull(oNasiel) ' Pokiaľ nájdeme (not nenájdenie)
  sPom=oNasiel.String ' Nájdený reťazec
  if len(sPom)>3 then ' Ak má význam sa vôbec zaoberať rádmi (viac ako trojciferné čísla)
   k=instr(sPom,",")+instr(sPom,".") ' Poloha desatinnej čiarky alebo bodky – môže byť iba jedno z nich, preto vyhovuje súčet
   if k=0 then k=len(sPom)+1 ' Ak nie je desatinná čiarka/bodka, tak je celé číslo – "poloha" desatinnej čiarky je dĺžka čísla +1
   if k>1 then ' Čísla v tvare ,123 (teda bez celej časti – vtedy sa k=1) nespracovávame
    sCela=left(sPom,k-1) ' Celá časť pred desatinnou čiarkou/bodkou
    sCela=trim(format(val(sCela), "#"+chr$(&HA0)+"##0")) ' Naformátujeme číslo – oddelíme rády nezalomiteľnou medzerou
    if k<>0 then
     sPom=sCela+right(sPom,len(sPom)-k+1) ' Ak bola desatinná časť, tak ju pridáme k naformátovanej celej časti (zachováme zadanú desatinnú čiarku/bodku)
    else
     sPom=sCela ' Ak nebola desatinná časť, ponecháme iba naformátovanú celú časť
    endif
    oNasiel.String=trim(sPom) ' Vlastná náhrada
    kolko=kolko+1 ' Počet nájdených výskytov
   endif
  end if
  oNasiel = oDokument.findNext(oNasiel.End, oHladaj) ' Hľadanie ďalšieho výskytu v dokumente
 Loop
 msgbox sText1+trim(str(kolko))+sText2 ' Výpis počtu naformátovaných čísiel
end sub


Neprehliadnite: